We are asking you to pay 8€ (around US$10) for downloading the application. This way we can ensure future releases, bugfixes and features.
アプリケーションのダウンロードには、8ユーロ(約US$10)の支払いをお願いしています。そうすることで、将来のリリース、バグフィックス、機能を確保することができます。
rem 01_Create_Build_directory.bat
echo %0
cd \
mkdir \00_fritzing
cd /d \00_fritzing
● 2) Fritzingのビルドに必要なファイルをダウンロードする
rem 02_Download_Requirement_Files.bat
echo %0
cd /d \00_fritzing
rem https://github.com/FREEWING-JP/CSharp_UnZip
rem C# UnZip .Net 4.5
bitsadmin /TRANSFER hoge https://github.com/FREEWING-JP/CSharp_UnZip/releases/download/v0.0/UnZip.exe %cd%\UnZip.exe
rem https://git-scm.com/download/win
rem Git - Downloading Package Download for Windows
bitsadmin /TRANSFER hoge https://github.com/git-for-windows/git/releases/download/v2.42.0.windows.2/PortableGit-2.42.0.2-64-bit.7z.exe %cd%\PortableGit-2.42.0.2-64-bit.7z.exe
rem https://www.7-zip.org/
rem 7-Zip
bitsadmin /TRANSFER hoge https://www.7-zip.org/a/7z2301-x64.exe %cd%\7z2301-x64.exe
rem https://learn.microsoft.com/ja-jp/visualstudio/install/build-tools-container?view=vs-2019
rem Build Tools
rem Visual Studio Build Tools 2019
bitsadmin /TRANSFER hoge https://aka.ms/vs/16/release/vs_BuildTools.exe %cd%\vs_BuildTools_2019.exe
rem Visual Studio Build Tools 2022
rem bitsadmin /TRANSFER hoge https://aka.ms/vs/17/release/vs_BuildTools.exe %cd%\vs_BuildTools_2022.exe
rem https://www.qt.io/download-qt-installer-oss
rem Qt Qt6
bitsadmin /TRANSFER hoge https://d13lb3tujbc8s0.cloudfront.net/onlineinstallers/qt-unified-windows-x64-4.6.1-online.exe %cd%\qt-unified-windows-x64-4.6.1-online.exe
rem https://www.boost.org/users/history/version_1_81_0.html
rem Boost Version 1.81.0
rem December 14th, 2022 17:44 GMT
bitsadmin /TRANSFER hoge https://boostorg.jfrog.io/artifactory/main/release/1.81.0/source/boost_1_81_0.zip %cd%\boost_1_81_0.zip
rem https://www.zlib.net/
rem zlib Home Site
bitsadmin /TRANSFER hoge https://www.zlib.net/zlib13.zip %cd%\zlib13.zip
rem https://sourceforge.net/projects/ngspice/files/ng-spice-rework/40/
rem ngspice Files
bitsadmin /TRANSFER hoge https://jaist.dl.sourceforge.net/project/ngspice/ng-spice-rework/40/ngspice-40.tar.gz %cd%\ngspice-40.tar.gz
bitsadmin /TRANSFER hoge https://master.dl.sourceforge.net/project/ngspice/ng-spice-rework/40/ngspice-40_dll_64.7z %cd%\ngspice-40_dll_64.7z
・Fritzingのビルドに必要な Visual Studio Build Toolsをインストールする
● 5) ダウンロードしたファイルを解凍する
rem 03_Extract_Requirement_Files.bat
cd /d \00_fritzing
UnZip.exe boost_1_81_0.zip .
UnZip.exe zlib13.zip .
tar -xf ngspice-40.tar.gz
7z2301-x64.exe /S /D=%cd%\7z
.\7z\7z x PortableGit-2.42.0.2-64-bit.7z.exe -o.\PortableGit
.\7z\7z x ngspice-40_dll_64.7z -o.\
● 6) Gitから Fritzingのビルドに必要なファイルをダウンロードする
rem 04_Download_from_Git.bat
echo %0
cd /d \00_fritzing
Path=%cd%\PortableGit\bin;%Path%
rem https://github.com/stachenov/quazip/releases
rem QuaZip v1.4
git clone https://github.com/stachenov/quazip -b v1.4 quazip-1.4
rem https://github.com/svgpp/svgpp/releases/tag/v1.3.0
rem SVG++ library 1.3.0
git clone https://github.com/svgpp/svgpp -b v1.3.0 svgpp-1.3.0
rem https://github.com/libgit2/libgit2/releases/tag/v0.28.5
rem libgit2 v0.28.5
git clone https://github.com/libgit2/libgit2 -b v0.28.5
● 7) Fritzingのビルドに必要なライブラリをビルドする
rem 07_Build_Library.bat
echo %0
cd /d \00_fritzing
Path=%cd%\PortableGit\bin;%Path%
rem Visual Studio 2019 Build Tools
"C:\Program Files (x86)\Microsoft Visual Studio\2019\BuildTools\Common7\Tools\VsDevCmd.bat"
echo Build Boost
cd boost_1_81_0
rem Visual Studio 16 2019 BuildTools VS2019 14.2
bootstrap.bat vc142
echo %cd%
set BOOST_DIR=%cd%
set BUILD_JOBS=%NUMBER_OF_PROCESSORS%
rem Visual Studio 16 2019 BuildTools VS2019 14.2
set TOOL_SET=msvc-14.2
b2.exe toolset=%TOOL_SET% link=static runtime-link=static,shared --build-dir=build/x64 address-model=64 -j%BUILD_JOBS% install --includedir=%BOOST_DIR%\include --libdir=%BOOST_DIR%\stage\lib\x64
cd ..
echo Build libgit2
cd libgit2
rmdir /S /Q build64
mkdir build64
cd build64
cmake .. -G "Visual Studio 16 2019" -A x64 -DBUILD_CLAR=OFF
cmake --build . --config Release
cd ..
cd ..
echo Build zlib
cd zlib-1.3
rmdir /S /Q build64
mkdir build64
cd build64
cmake .. -G "Visual Studio 16 2019" -A x64
msbuild /P:Configuration=Release ALL_BUILD.vcxproj
cd ..
rem -- Renaming
rem -- C:/00_fritzing/zlib-1.3/zconf.h
rem -- to 'zconf.h.included' because this file is included with zlib
rem -- but CMake generates it automatically in the build directory.
copy zconf.h.included zconf.h
cd ..
echo Build quazip
cd quazip-1.4
dir ..\zlib-1.3\build64\Release\zlib.lib
set Qt6_DIR=C:\Qt\6.5.3\msvc2019_64
dir %Qt6_DIR%
rmdir /S /Q build64
mkdir build64
cmake -S . -B build64 ^
-G "Visual Studio 16 2019" -A x64 ^
-D QUAZIP_QT_MAJOR_VERSION=6 ^
-D CMAKE_INSTALL_PREFIX=..\quazip_qt6 ^
-D QUAZIP_USE_QT_ZLIB=OFF ^
-D ZLIB_INCLUDE_DIR=..\zlib-1.3 ^
-D ZLIB_LIBRARY=%cd%\..\zlib-1.3\build64\Release\zlib.lib
cmake --build build64 --config Release
cmake --build build64 --config Release --target install
cd ..
rem Project ERROR: quazip include path not found in C:/00_fritzing/quazip_qt6/include/quazip
dir .\quazip_qt6\include\QuaZip-Qt6-1.4\quazip
xcopy .\quazip_qt6\include\QuaZip-Qt6-1.4\quazip .\quazip_qt6\include\quazip\
rem Project ERROR: quazip library not found in C:/00_fritzing/quazip_qt6/build64/Release
dir .\quazip_qt6\bin
dir .\quazip_qt6\lib
xcopy .\quazip_qt6\bin .\quazip_qt6\build64\Release\
xcopy .\quazip_qt6\lib\*.lib .\quazip_qt6\build64\Release\
dir .\quazip_qt6\build64\Release\
● 8) Fritzingのビルドに必要なライブラリを配置する
● 9) Fritzingのソースリストを Git cloneでダウンロードする
rem 08_Download_Fritzing_Source_code.bat
echo %0
cd /d \00_fritzing
git clone https://github.com/fritzing/fritzing-app.git -b develop
cd fritzing-app
git rev-parse --git-dir
cd ..
● 10) Fritzingのパーツを Git cloneでダウンロードする
rem 09_Download_Fritzing_Parts_Library.bat
echo %0
cd /d \00_fritzing
mkdir release64
cd release64
git clone https://github.com/fritzing/fritzing-parts -b 1.0.1
cd ..
● 11) Fritzingのソースリストを修正する
Fritzingチームのトラップでしょうか?
modelbase.cpp:857:7: No viable conversion from 'ParseResult' to 'bool'
qdom.h:281:18: explicit conversion function is not a candidate
modelbase.cpp
QDomDocument oldDoc;
bool ok = oldDoc.setContent(&newFzp);
を
QDomDocument oldDoc;
bool ok = oldDoc.setContent(&newFzp, nullptr);
に書き換える。
QDomDocument oldDoc;
bool ok = oldDoc.setContent(&newFzp).errorMessage.isEmpty();
に書き換えるでも可。
rem 10_Fix_Fritzing_Source_code.bat
echo %0
cd /d \00_fritzing
cd fritzing-app
cd .\src\model
powershell -Command "gc modelbase.cpp | % { $_ -creplace 'oldDoc.setContent(&newFzp);', 'oldDoc.setContent(&newFzp, nullptr);' } > modelbase.cpp_tmp"
del modelbase.cpp
ren modelbase.cpp_tmp modelbase.cpp
cd /d \00_fritzing
:-1: error: dependent 'ui_exportparametersdialog.h' does not exist.
:-1: error: dependent 'ui_fabuploaddialog.h' does not exist.
rem 11_Fix_Fritzing_Missing_Header_files.bat
echo %0
cd /d \00_fritzing
cd fritzing-app
C:\Qt\6.5.3\msvc2019_64\bin\qmake.exe -o Makefile phoenix.pro "QMAKE_TARGET.arch=x86_64"
C:\Qt\Tools\QtCreator\bin\jom\jom.exe -f Makefile.Debug compiler_uic_make_all
DIR ..\debug64\ui_*.h
xcopy ..\debug64\*.h ..\fritzing_h\
xcopy ..\fritzing_h\ ..\release64\