・2019/08/02
Windows 10 May 2019 Update 1903の ISOインストールイメージに Windows Updateを統合する方法
(予め ISOインストールイメージに Windows Updateを適用しておいてインストール後の WUの手間を無くす方法)
Tags: [Windows], [無人インストール]
● Windows 10 May 2019 Update 1903 19H1の Windows Update
略語 | 日本語の意味 | 英語の原文 |
LCU | 最新の累積更新プログラム | Latest Cumulative Update |
SSU | サービス スタック更新プログラム | Servicing Stack Update |
Windows 10 May 2019 Update 1903 19H1の Windows Update情報はこちらをご覧ください。
・2019/09/07
【更新終了】Windows 10 May 2019 Update 1903 19H1 18362の Windowsアップデート情報まとめ
Windows 10 May 2019 1903の Windows Updateのまとめ
● Windows 10 May 2019 Update 1903 19H1の Windows Update
● 2019/07/26 18362.267
July 26, 2019 OS Build 18362.267 KB4505903
July 26, 2019 - KB4505903 (OS Build 18362.267)
latest SSU KB4508433
Windows 10、1903 のバージョン用の更新プログラムのスタック処理: 2019 年 7 月 26日
● Windows 10 May 2019 Update 1903に Windows Updateを統合する方法
予め Windowsのインストールイメージに Windows Updateを適用しておいてインストール後の Windows Updateの手間を無くすのが目的。
必要な物
・Windows 10 May 2019 Update 1903の ISOファイル
・サービス スタック更新プログラム
・最新の累積更新プログラム
その他
・Windows 10が動作する環境
・HDD/ SSDの空き容量 30GB程度
● Windows 10 May 2019 Update 1903の ISOファイル
Windows 10 のダウンロード
MediaCreationTool1903.exeを使って Windows 10 May 2019 Updateの ISOをダウンロードします。
2019/07現在の ISOイメージのタイムスタンプ:2019/06/12 10.0.18362.175
● Windows 10 May 2019 Update 1903に Windows Updateを統合するバッチファイル
下記のバッチファイルは
D:\Win10
に必要なファイルをダウンロードして処理します。
途中で Windows 10の ISOの中身を D:\Win10\ISOにコピーしてください。
Windows 10の ISOをダブルクリックでマウントして全ファイルをコピーする。
Windows 10 Proを処理対象にしています。Homeの場合は書き換えてください。
@echo off
rem 文字コードは Shift-JISで保存します。
rem 他の文字エンコードだと日本語が文字化けします。
echo ====
rem 必要に応じて書き換える
set WIN10_EDITION=Windows 10 Pro
rem 必要に応じて書き換える
set WIN10_BASE=D:\Win10
mkdir %WIN10_BASE%
cd /d %WIN10_BASE%
set TMP_DIR=%WIN10_BASE%\TMP
set MSU_DIR=%WIN10_BASE%\MSU
set WIN_ISO=%WIN10_BASE%\ISO
rmdir /S /Q %TMP_DIR%
mkdir %TMP_DIR%
mkdir %MSU_DIR%
mkdir %WIN_ISO%
echo Windows 10の ISOの中身を %WIN_ISO%にコピーしてください
pause
dir %WIN_ISO%
if not exist %WIN_ISO%\setup.exe goto COPY_NG
if not exist %WIN_ISO%\sources\install.esd goto COPY_NG
goto COPY_OK
:COPY_NG
echo Windows 10の ISOの中身のコピーが失敗しています
pause
exit /b
:COPY_OK
if exist %MSU_DIR%\LCU.msu goto MSU_OK
echo ====
echo 更新プログラムのダウンロード
echo 2019/07/26
rem Microsoft Update カタログ
rem https://www.catalog.update.microsoft.com/Search.aspx?q=1903%202019-07%20x64
set SSU_MSG=2019-07 Servicing Stack Update for Windows 10 Version 1903 x64 (KB4508433)
set SSU_URL=http://download.windowsupdate.com/c/msdownload/update/software/secu/2019/07/windows10.0-kb4508433-x64_c4d6ffb6ee72a39da6c6c7e15a47d6e1520030e4.msu
set LCU_MSG=2019-07 Cumulative Update for Windows 10 Version 1903 x64 (KB4505903)
set LCU_URL=http://download.windowsupdate.com/c/msdownload/update/software/updt/2019/07/windows10.0-kb4505903-x64_af8c6ab868423055a750797b6d52c1bd67e15a95.msu
rem bitsadmin - Microsoft Docs
rem https://docs.microsoft.com/ja-jp/windows-server/administration/windows-commands/bitsadmin
echo %SSU_MSG%
bitsadmin /transfer download %SSU_URL% %MSU_DIR%\SSU.msu
if errorlevel 1 goto MSU_NG
echo %LCU_MSG%
bitsadmin /transfer download %LCU_URL% %MSU_DIR%\LCU.msu
if errorlevel 1 goto MSU_NG
goto MSU_OK
:MSU_NG
echo 更新プログラムのダウンロードに失敗しました
pause
exit /b
:MSU_OK
dir %MSU_DIR%
rem DISM のイメージの管理コマンド ライン オプション
rem https://docs.microsoft.com/ja-jp/windows-hardware/manufacture/desktop/dism-image-management-command-line-options-s14
echo ====
echo Windowsイメージの確認
Dism /Get-WIMInfo /WimFile:%WIN_ISO%\sources\install.esd
rem 展開イメージのサービスと管理ツール
rem バージョン: 10.0.18362.1
rem イメージの詳細: D:\Win10\ISO\sources\install.esd
rem .
rem インデックス: 1
rem 名前: Windows 10 Home
rem 説明: Windows 10 Home
rem サイズ: 14,736,050,187 バイト
rem .
rem インデックス: 2
rem 名前: Windows 10 Education
rem 説明: Windows 10 Education
rem サイズ: 15,013,362,594 バイト
rem .
rem インデックス: 3
rem 名前: Windows 10 Pro
rem 説明: Windows 10 Pro
rem サイズ: 15,013,585,151 バイト
rem .
rem 操作は正常に完了しました。
echo ====
echo Windowsイメージの展開
echo install.esdを install.wimに展開
cd %WIN_ISO%\sources
if exist install.wim del install.wim
if exist install_.esd del install_.esd
Dism /Export-Image /SourceImageFile:install.esd /SourceName:"%WIN10_EDITION%" /DestinationImageFile:install.wim /Compress:max /CheckIntegrity
rem 展開イメージのサービスと管理ツール
rem バージョン: 10.0.18362.1
rem イメージをエクスポートしています
rem [==========================100.0%==========================]
rem 操作は正常に完了しました。
dir install*.*
rem 2019/07/10 23:00 3,445,695,924 install.esd
rem 2019/08/00 13:46 4,123,713,942 install.wim
echo ====
echo Windowsイメージの確認
cd %WIN10_BASE%
Dism /Get-WIMInfo /WimFile:%WIN_ISO%\sources\install.wim
rem インデックス: 1
rem 名前: Windows 10 Pro
rem 説明: Windows 10 Pro
rem サイズ: 15,013,585,151 バイト
echo ====
echo Windowsイメージのマウント
echo install.wimファイルをマウント
Dism /Mount-WIM /WimFile:%WIN_ISO%\sources\install.wim /Name:"%WIN10_EDITION%" /MountDir:%TMP_DIR%
if errorlevel 1 goto DISM_NG
goto DISM_OK
rem イメージをマウントしています
rem [==========================100.0%==========================]
rem 操作は正常に完了しました。
rem このエラーが出たら最初からやり直す
rem エラー: 0xc1420127
rem 指定した WIM の指定したイメージは、既に読み取り/書き込みアクセス用にマウントされています。
:DISM_NG
echo Windowsイメージのマウントに失敗しました
pause
exit /b
:DISM_OK
echo ====
echo 更新プログラムの適用
echo SSU
Dism /Image:%TMP_DIR% /Add-Package /PackagePath:%MSU_DIR%\SSU.msu
rem イメージのバージョン: 10.0.18362.175
rem 1 / 1 を処理しています - パッケージ D:\Win10\MSU\SSU.msu を追加しています
rem [==========================100.0%==========================]
rem 操作は正常に完了しました。
echo LCU
Dism /Image:%TMP_DIR% /Add-Package /PackagePath:%MSU_DIR%\LCU.msu
rem イメージのバージョン: 10.0.18362.175
rem 1 / 1 を処理しています - パッケージ D:\Win10\MSU\LCU.msu を追加しています
rem [==========================100.0%==========================]
rem 操作は正常に完了しました。
echo ====
echo Windowsイメージのコミット(変更内容の反映)
Dism /Commit-Image /MountDir:%TMP_DIR% /CheckIntegrity
rem イメージを保存しています
rem [==========================100.0%==========================]
rem 操作は正常に完了しました。
echo ====
echo Windowsイメージのマウントを解除(アンマウント)
Dism /Unmount-Image /MountDir:%TMP_DIR% /Commit
rem イメージを保存しています
rem [==========================100.0%==========================]
rem イメージのマウントを解除しています
rem [==========================100.0%==========================]
rem エラーが出ても無視する
rem エラー: 0xc1420117
rem ディレクトリを完全にはマウント解除できませんでした。
rem これは通常、アプリケーションがマウント ディレクトリ内のファイルを開いていることが原因です。
rem マウント解除のプ ロセスを完了するには、これらのファイルを閉じてから、再度マウントを解除してください。
rem 上記エラーのおまじない
Dism /Cleanup-Mountpoints
Dism /Cleanup-WIM
echo ====
echo Windowsイメージの圧縮
echo install.wimを install.esdに圧縮
cd %WIN_ISO%\sources
Dism /Export-Image /SourceImageFile:install.wim /SourceName:"%WIN10_EDITION%" /DestinationImageFile:install_.esd /Compress:recovery /CheckIntegrity
dir install*.*
rem 2019/07/10 23:00 3,445,695,924 install.esd
rem 2019/08/00 14:01 4,853,252,374 install.wim
rem 2019/08/00 14:23 3,446,495,880 install_.esd
echo ====
echo 不要ファイルの削除
del install.wim
echo install.esdファイルを上書き
del install.esd
ren install_.esd install.esd
echo ====
echo Windowsの更新が完了
echo %WIN_ISO%の中身を USBメディアにコピーしてください
rem USBメディアを使用して UEFIでのインストールなので ISOイメージの作成は行ないません
pause
● Dismコマンド
DISM のイメージの管理コマンド ライン オプション
> Dism
展開イメージのサービスと管理ツール
バージョン: 10.0.18362.1
DISM.exe [dism_options] {Imaging_command} [<イメージング引数>]
DISM.exe {/Image:<オフライン イメージのパス> | /Online} [dism_options]
{servicing_command} [<サービス引数>]
説明:
DISM は、Windows イメージの機能とパッケージを列挙、インストール、
アンインストール、構成、および更新します。使用できるコマンドは、サービス
するイメージによって、またイメージがオフラインか実行中かによって異なります。
汎用イメージング コマンド:
/Split-Image - 既存の .wim ファイルを複数の読み取り専用の
分割 WIM (SWM) ファイルに分割します。
/Apply-Image - イメージを適用します。
/Get-MountedImageInfo - マウントされた WIM および VHD イメージに関する
情報を表示します。
/Get-ImageInfo - WIM、VHD、または FFU ファイル内のイメージに関する情報を
表示します。
/Commit-Image - マウントされた WIM または VHD イメージへの変更を
保存します。
/Unmount-Image - マウントされた WIM または VHD イメージのマウントを
解除します。
/Mount-Image - WIM または VHD ファイルからイメージをマウント
します。
/Remount-Image - 孤立したイメージ マウント ディレクトリを回復します。
/Cleanup-Mountpoints - マウント済みの破損したイメージに関連付けられ
ているリソースを削除します。
WIM コマンド:
/Apply-CustomDataImage - カスタム データ イメージに含まれているファイルを退避します。
/Capture-CustomImage - カスタマイズを WIMBoot システム上のデルタ WIM
ファイルにキャプチャします。キャプチャされる
ディレクトリには、すべてのサブフォルダーとデータが
含まれます。
/Get-WIMBootEntry - 指定したディスク ボリュームの
WIMBoot 構成エントリを表示します。
/Update-WIMBootEntry - 指定したディスク ボリュームの
WIMBoot 構成エントリを更新します。
/List-Image - 指定したイメージ内のファイルとフォルダーの一覧を
表示します。
/Delete-Image - 指定したボリューム イメージを、複数のボリューム
イメージがある WIM ファイルから削除します。
/Export-Image - 指定したイメージのコピーを別のファイルにエクスポート
します。
/Append-Image - 別のイメージを WIM ファイルに追加します。
/Capture-Image - ドライブのイメージを新しい WIM ファイルに
キャプチャします。
キャプチャされるディレクトリには、すべての
サブフォルダーとデータが含まれます。
/Get-MountedWimInfo - マウントされた WIM イメージに関する情報を表示します
/Get-WimInfo - WIM ファイル内のイメージに関する情報を表示します。
/Commit-Wim - マウントされた WIM イメージへの変更を保存します。
/Unmount-Wim - マウントされた WIM イメージのマウントを解除します。
/Mount-Wim - WIM ファイルからイメージをマウントします。
/Remount-Wim - 孤立した WIM マウント ディレクトリを回復します。
/Cleanup-Wim - マウント済みの破損した WIM イメージに関連付けられ
ているリソースを削除します。
FFU COMMANDS:
/Capture-Ffu - Captures a physical disk image into a new FFU file.
/Apply-Ffu - Applies an .ffu image.
/Split-Ffu - Splits an existing .ffu file into multiple read-only
split FFU files.
イメージの指定:
/Online - 実行中のオペレーティング システムをターゲットに
します。
/Image - オフライン Windows イメージのルート ディレクトリ
へのパスを指定します。
DISM オプション:
/English - コマンド ライン出力を英語で表示します。
/Format - レポートの出力形式を指定します。
/WinDir - Windows ディレクトリへのパスを指定します。
/SysDriveDir - BootMgr という名前のシステム ローダー ファイルへの
パスを指定します。
/LogPath - ログ ファイルのパスを指定します。
/LogLevel - ログに表示する出力レベルを指定します (1-4)。
/NoRestart - 自動再起動と再起動の確認要求を抑制します。
/Quiet - エラー メッセージを除き、すべての出力を抑制します。
/ScratchDir - スクラッチ ディレクトリへのパスを指定します。
これらの DISM オプションおよびその引数の詳細については、オプションの
直後に /? を指定してください。
例:
DISM.exe /Mount-Wim /?
DISM.exe /ScratchDir /?
DISM.exe /Image:C:\test\offline /?
DISM.exe /Online /?
エラー: 0xc1420117
ディレクトリを完全にはマウント解除できませんでした。これは通常、アプリケーションがマウント ディレクトリ内のファイルを開いていることが原因です。マウント解除のプ ロセスを完了するには、これらのファイルを閉じてから、再度マウントを解除してください。
エラー: 0xc142011d
指定されたマウント済みイメージを WIM にコミットして戻すことができません。これは イメージの一部のみがマウント解除されていたり、イメージがマウント中であることが原因です。以前にこのイメージをコミットしてマウント解除したことがある場合は、コミットは正常に終了した可能性があります。コミットが正常に終了しているかどうかを確認してから、コミットなしでマウント解除してください。
エラー: 2
指定されたファイルが見つかりません。
エラー: 11
間違ったフォーマットのプログラムを読み込もうとしました。
エラー: 123
ファイル名、ディレクトリ名、またはボリューム ラベルの構文が間違っています。
●動作中の Windows 10に更新プログラムを全自動で適用する方法
更新プログラムを全自動でダウンロードして動作中の Windows 10に適用する方法。
echo ====
echo 更新プログラムのダウンロード
echo 2019/07/26
rem Microsoft Update カタログ
rem https://www.catalog.update.microsoft.com/Search.aspx?q=1903%202019-07%20x64
set SSU_MSG=2019-07 Servicing Stack Update for Windows 10 Version 1903 x64 (KB4508433)
set SSU_URL=http://download.windowsupdate.com/c/msdownload/update/software/secu/2019/07/windows10.0-kb4508433-x64_c4d6ffb6ee72a39da6c6c7e15a47d6e1520030e4.msu
set LCU_MSG=2019-07 Cumulative Update for Windows 10 Version 1903 x64 (KB4505903)
set LCU_URL=http://download.windowsupdate.com/c/msdownload/update/software/updt/2019/07/windows10.0-kb4505903-x64_af8c6ab868423055a750797b6d52c1bd67e15a95.msu
rem bitsadmin - Microsoft Docs
rem https://docs.microsoft.com/ja-jp/windows-server/administration/windows-commands/bitsadmin
echo %SSU_MSG%
bitsadmin /transfer download %SSU_URL% %MSU_DIR%\SSU.msu
if errorlevel 1 goto MSU_NG
echo %LCU_MSG%
bitsadmin /transfer download %LCU_URL% %MSU_DIR%\LCU.msu
if errorlevel 1 goto MSU_NG
goto MSU_OK
:MSU_NG
echo 更新プログラムのダウンロードに失敗しました
exit /b
:MSU_OK
dir %MSU_DIR%
echo //========
echo 更新プログラムの適用
echo SSU
echo %SSU_MSG%
start /wait /high SSU.msu /quiet /norestart
echo //========
echo LCU
echo %LCU_MSG%
start /wait /high LCU.msu /quiet /norestart
pause
Tags: [Windows], [無人インストール]
●関連するコンテンツ(この記事を読んだ人は、次の記事も読んでいます)
【2020年版】Windows 10 May 2020 Update 2004 20H1 Build 19041の Windowsアップデート情報まとめ
【更新終了】Windows 10 May 2020 Update 2004 20H1 Build 19041の Windows Updateのまとめ
Windows 10の裏メニュー ゴッドモード(神モード)を出現させる方法
Windows 10の裏コマンド 神モード GodModeを使う方法、{ED7BA470-8E54-465E-825C-99712043E01C}
Windows 10を全自動で最後まで手間要らずでインストールする方法
autounattend.xmlの応答ファイルを使用して Windows 10を無人インストールする。大量展開時に便利
ここが変だよ Windows 10!Windows 10の不可解な挙動やバグの解決方法
Windows 10の変な挙動のまとめとその解決方法、不具合やバグを「仕様」と言い張るマイクソソフト
Windows 10の ISOを無料でダウンロードする方法、インストール DVD・USBを作成する方法
マイクロソフトの公式サイトから最新版の Windows 10のインストール ISOイメージをダウンロード
Windows 10 April 2018 Update Build 1803にマイナーバージョンの存在
MediaCreationToolでダウンロードした Windows.isoは微妙に更新されています
2020年対応 Windows 7や 8.1から Windows 10 April 2018 Updateへ無償で公式アップグレードする方法
2020年現在も Windows 7から Win10への無料アップグレードが可能です、Windows10Upgrade24074.exe
Windows 10をインストールする時にできる 500MBの「回復パーティション」を削除する方法
500MBの領域が勿体無いので Windows 10の回復パーティションを削除する手順(再インストール必要)
Windows 10 October 2018 Update 1809 17763 RS5の ISOをダウンロードする方法、インストール DVD・USBを作成する方法
最新版の Windows 10 October 2018 Updateのインストール ISOイメージを公式サイトからダウンロード
Windows Insider Programに参加して最新の Windows 10を入手する方法、17763.107が欲しい!!
Windows 10 October 2018 Update 1809 RS5の最新パッチを入手する為に Windows Insider Programに参加
Intel CPUで有名な Meltdownと Spectreの脆弱性を InSpectreアプリでチェックする
Windows OS上で CPUのスペクターとメルトダウンの脆弱性をチェックできるアプリ InSpectre
Windows 10用の Spectre脆弱性対応の CPUマイクロコード更新プログラム KB4465065
Intel CPUの Spectreの脆弱性を修正するマイクロソフト Windows用 更新プログラム KB4465065
Microsoft Office 365を無人インストール(自動インストール)する方法
インストールするコンポーネントを事前に設定する事で同一環境の構築が楽にできます MSオフィス 365
Adobe Acrobat Reader関係のまとめ 2018年版、自動インストール、無人インストール方法
アップデート手順など、Adobe Reader XI、X、Acrobat Reader 9、Acrobat Reader 8
【2023年対応】 Microsoft Visual C++ ランタイムライブラリ 再頒布可能パッケージのまとめ 2005~2022まで
Microsoft Visual C++ 2005、2008、2010、2012、2013、2015、2017、2019、2022の各バージョンの最新版 MSVC Runtime librariesのまとめ
Visual Studio 2019 Professional v16.4を無人インストールする方法、完全自動でインストール
VS2019 v16.4を完全オフラインインストール&コンポーネント選択の事前設定で自動インストールする
[HOME]
|
[BACK]
リンクフリー(連絡不要、ただしトップページ以外は Web構成の変更で移動する場合があります)
Copyright (c)
2019 FREE WING,Y.Sakamoto
Powered by 猫屋敷工房 & HTML Generator
http://www.neko.ne.jp/~freewing/software/windows_10_dism_slipstream_windows_update_install_esd/